发表回复 
问题·未解决 GUI ask you
2017-04-23, 16 : 01
RE: gui的CheckBox問題想請教各位大哥
@feiyue 請問熱鍵2跟熱鍵6這樣寫 無法執行的原因是..? 謝謝唷

MsgBox, 0, , 警告!!腳本並沒有修改到遊戲內部,但腳本仍屬於第三方程式,若被偵測導致帳號被封鎖,作者一律不負責。
IfMsgBox, No
return
MsgBox 提醒您!!啟動腳本後按熱鍵沒反應請關閉腳本程式再以「系統管理員身份開啟」
MsgBox 歡迎使用Johnson的CSOnline腳本,祝您遊玩愉快。
MsgBox 已成功啟動腳本。

Suspend, On

熱鍵1= $LShift
熱鍵2= $MButton
熱鍵3= $E
熱鍵4= $F1
熱鍵5= $T
熱鍵6= $MButton

Loop, 6
Hotkey, % 熱鍵%A_Index%, Off

Gui, Font, c0080FF
Gui, Color, 000000
Gui, Font, s14
Gui, Add, Checkbox, v勾選總開關 g執行勾選, 啟動腳本程式
Gui, Add, Text,, ║腳本作者:Johnson Chiang
Gui, Add, Text,, ║現在時間:%A_YYYY%年%A_MM%月%A_DD%日
Gui, Add, Text,, ║使用期限:無限制
Gui, Add, Text,, ║版本資訊:Ver.3.0
Gui, Font, s13
Gui, Add, Text,, ................................
Gui, Add, Text,, 蓋亞之狂、血獄之淵連敲腳本
Gui, Add, Checkbox, v勾選熱鍵1 g執行勾選, 熱鍵:Shift
Gui, Add, Checkbox, v勾選熱鍵2 g執行勾選, 熱鍵:滑鼠中鍵
Gui, Add, Checkbox, v勾選熱鍵3 g執行勾選, 熱鍵:E鍵
Gui, Add, Checkbox, v勾選熱鍵4 g執行勾選, 熱鍵:F1開關
Gui, Add, Checkbox, v勾選熱鍵5 g執行勾選, 熱鍵:T開關
Gui, Add, Text,, ................................
Gui, Add, Checkbox, v勾選熱鍵6 g執行勾選, 熱鍵:滑鼠中鍵GS腳本

Gui, Show, w500 h390, CSO蓋亞之狂、血獄之淵狂敲腳本 By Johnson Chiang

執行勾選:
;-- 讀取所有選項的值到對應變量中
Gui, Submit, NoHide

;-- 允許或禁止所有熱鍵,註意右下角程序圖標會改變
Suspend, % 勾選總開關 ? "Off":"On"

;-- 允許或禁止各個熱鍵
Loop, 6
Hotkey, % 熱鍵%A_Index%, % 勾選熱鍵%A_Index% ? "On":"Off"
return


;=============== 後面的是各個熱鍵的代碼 ===============


$LShift: ;-- 熱鍵1
Loop 9999
{
If Not GetKeyState("LShift", "P")
Break
SendInput {q}
SendInput {3}
}
Return

$MButton: ;-- 熱鍵2
Loop 9999
{
If Not GetKeyState("MButton", "P")
Break
SendInput {q}
Sleep 358
}
Return

$E: ;-- 熱鍵3
Loop 9999
{
If Not GetKeyState("E", "P")
Break
SendInput {RButton up}
Sleep 271
}
Return

#MaxThreadsPerHotkey 2

$F1: ;-- 熱鍵4

PressKey := ! PressKey

Loop 9999
{
If ! PressKey
Break
SendInput {q}
SendInput {RButton up}
Sleep 271
}
Return

#MaxThreadsPerHotkey 1

#MaxThreadsPerHotkey 2

$T: ;-- 熱鍵5

PressKey := ! PressKey

Loop 9999
{
If ! PressKey
Break
Sleep 2.25
Sleep 268
}
Return

#MaxThreadsPerHotkey 1

$MButton: ;-- 熱鍵6
Loop 9999
{
If Not GetKeyState("MButton", "P")
Break
SendInput {Ctrl}
Sleep 237
}
Return

GuiClose:
ExitApp
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2017-04-23, 16 : 25 (这个帖子最后修改于: 2017-04-24 22 : 39 by feiyue.)
RE: gui的CheckBox問題想請教各位大哥
你这个要修改一下。两个同名的标签肯定不行呀。代码看24楼的吧。
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
[+] 1用户表示感谢feiyue
2017-04-23, 16 : 28 (这个帖子最后修改于: 2017-04-23 17 : 13 by johnsonchiang.)
RE: gui的CheckBox問題想請教各位大哥
@feiyue 我試試!! feiyue大 你真的好厲害 小弟感激不盡!!

@feiyue 只要標籤不同即可嗎?

@feiyue 請問總共可以重複幾個標籤??

@feiyue 能重複超過2個嗎?? 到4~7個這樣 感謝您
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2017-04-23, 19 : 48 (这个帖子最后修改于: 2017-04-24 23 : 26 by feiyue.)
RE: gui的CheckBox問題想請教各位大哥
@johnsonchiang 你之后的问题我都更新在这个儿,请下载最新的代码。
注意:重复使用的热键,最后一个打勾的有效。重复次数没有限制。

代码: (全选)
Suspend, On

MsgBox, 4,, 警告!!腳本並沒有修改到遊戲內部,但腳本仍屬於第三方程式,若被偵測導致帳號被封鎖,作者一律不負責。
IfMsgBox, No
  ExitApp
MsgBox 提醒您!!啟動腳本後按熱鍵沒反應請關閉腳本程式再以「系統管理員身份開啟」
MsgBox 歡迎使用Johnson的CSOnline腳本,祝您遊玩愉快。
MsgBox 已成功啟動腳本。

;-- 熱鍵變量統一賦值為:熱鍵 @ 標籤 @ T允許線程數

hotkey1= $LShift  @ $LShift    @ T1
hotkey2= $MButton @ $MButton   @ T1
hotkey3= $E       @ $E         @ T1
hotkey4= $F1      @ $F1        @ T2
hotkey5= $T       @ $T         @ T2
hotkey6= $MButton @ $MButton_1 @ T1
hotkey7= $MButton @ $MButton_2 @ T1
hotkey8= $MButton @ $MButton_3 @ T1

;-- 生成GUI窗口
Gui, Margin, 15, 15
Gui, Color, 000000
Gui, Font, s14 c99DDFF
Gui, Add, Checkbox, vCheck_all_hotkey gRunCheck, 啟動腳本程式
Gui, Font, s13
Gui, Add, Tab3, w500 -Wrap, 常規|高級|其他|關於
;-----------------------------------------
Gui, Tab, 1
Gui, Add, Text, r1, .................
Gui, Add, Text,, 蓋亞之狂、血獄之淵連敲腳本
Gui, Add, Checkbox, vCheck_hotkey1 gRunCheck, 熱鍵:Shift
Gui, Add, Checkbox, vCheck_hotkey2 gRunCheck, 熱鍵:滑鼠中鍵
Gui, Add, Checkbox, vCheck_hotkey3 gRunCheck, 熱鍵:E鍵
Gui, Add, Checkbox, vCheck_hotkey4 gRunCheck, 熱鍵:F1開關
Gui, Add, Checkbox, vCheck_hotkey5 gRunCheck, 熱鍵:T開關
;-----------------------------------------
Gui, Tab, 2
Gui, Add, Text, r1, .................
Gui, Add, Checkbox, vCheck_hotkey6 gRunCheck, 熱鍵:滑鼠中鍵GS腳本1
Gui, Add, Checkbox, vCheck_hotkey7 gRunCheck, 熱鍵:滑鼠中鍵GS腳本2
Gui, Add, Checkbox, vCheck_hotkey8 gRunCheck, 熱鍵:滑鼠中鍵GS腳本3
;-----------------------------------------
Gui, Tab, 4
Gui, Add, Text,, ║腳本作者:Johnson Chiang
Gui, Add, Text,, ║現在時間:%A_YYYY%年%A_MM%月%A_DD%日
Gui, Add, Text,, ║使用期限:無限制
Gui, Add, Text,, ║版本資訊:Ver.3.0
;-----------------------------------------
Gui, Tab
Gui, Show,, CSO蓋亞之狂、血獄之淵狂敲腳本 By Johnson Chiang
return

GuiClose:
ExitApp

RunCheck:

;-- 讀取所有選項的值到對應變量中
Gui, Submit, NoHide

;-- 允許或禁止所有熱鍵,註意右下角程序圖標會改變
Suspend, % Check_all_hotkey ? "Off":"On"

;-- 允許或禁止各個熱鍵
Loop, 8
{
  ok:=Check_hotkey%A_Index% ? "On":"Off"
  StringSplit, r, hotkey%A_Index%, @, " `t"
  if (r1=r2) or (ok="On")
    Hotkey, %r1%, %r2%, %ok% %r3%
}
return

;-- 延時取存在微小誤差的隨機數,避免外掛檢測
Sleep( ms_time, cha=20 ) {
  Random, t, ms_time-cha, ms_time+cha
  Sleep, t
}

;=============== 後面的是各個熱鍵的代碼 ===============


$LShift:    ;-- 熱鍵1
Loop 9999
{
  If Not GetKeyState("LShift", "P")
    Break
  SendInput {q}
  SendInput {3}
  Sleep( 30 )    ;-- 每次循環必須有一定的延時
}
Return


$MButton:    ;-- 熱鍵2
Loop 9999
{
  If Not GetKeyState("MButton", "P")
    Break
  SendInput {q}
  Sleep( 358 )
}
Return


$E:    ;-- 熱鍵3
Loop 9999
{
  If Not GetKeyState("E", "P")
    Break
  SendInput {RButton up}
  Sleep( 271 )
}
Return


$F1:    ;-- 熱鍵4
PressKey1 := !PressKey1
Loop 9999
{
  if (A_ThisHotkey!=A_ThisLabel)
    PressKey1:=0
  if (!PressKey1)
    Break
  SendInput {q}
  SendInput {RButton up}
  Sleep( 271 )
}
Return


$T:    ;-- 熱鍵5
PressKey2 := !PressKey2
Loop 9999
{
  if (A_ThisHotkey!=A_ThisLabel)
    PressKey2:=0
  if (!PressKey2)
    Break
  Sleep( 225 )    ;-- 這裡有錯誤
  Sleep( 268 )
}
Return


$MButton_1:    ;-- 熱鍵6 標籤
Loop 9999
{
  If Not GetKeyState("MButton", "P")
    Break
  SendInput {1}
  Sleep( 237 )
}
Return


$MButton_2:    ;-- 熱鍵7 標籤
Loop 9999
{
  If Not GetKeyState("MButton", "P")
    Break
  SendInput {2}
  Sleep( 237 )
}
Return


$MButton_3:    ;-- 熱鍵8 標籤
Loop 9999
{
  If Not GetKeyState("MButton", "P")
    Break
  SendInput {3}
  Sleep( 237 )
}
Return
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
[+] 1用户表示感谢feiyue
2017-04-24, 18 : 54 (这个帖子最后修改于: 2017-04-24 19 : 38 by johnsonchiang.)
RE: GUI ask you
@feiyue 試問大大為何hotkey5 and 6 線成數是t5

hotkey1= $LShift @ $LShift @ T1
hotkey2= $MButton @ $MButton @ T1
hotkey3= $E @ $E @ T1
hotkey4= $F1 @ $F1 @ T5
hotkey5= $T @ $T @ T5
hotkey6= $MButton @ $MButton_1 @ T1
hotkey7= $MButton @ $MButton_2 @ T1
hotkey8= $MButton @ $MButton_3 @ T1

@feiyue ahk有辦法在同一個執行檔寫兩個GUI嗎?
像是這樣子的:[Image: wcljio.png]
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2017-04-24, 22 : 23 (这个帖子最后修改于: 2017-04-24 22 : 44 by feiyue.)
RE: GUI ask you
@johnsonchiang 请参考24楼最新的代码。
实现多页面很简单,用Tab3控件就行了。看看AHK帮助吧,里面有Tab3的详细说明。
hotkey5 and 6 的允许线程数是5是随便设的,只要大于1就行了。
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
[+] 1用户表示感谢feiyue
2017-04-25, 14 : 22
RE: GUI ask you
@feiyue 了解 非常感謝您!
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2017-04-26, 12 : 58
RE: GUI ask you
@feiyue 大大,這幾天非常感謝您,
未來我若有問題還請大大包容,
小弟發問前都是先爬文過的,若還是看不懂才會發問,還請大大包容 Smile
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
发表回复 


论坛跳转:


联系我们 | Autohotkey 中文站 | 回到顶部 | 回到正文区 | 精简(归档)模式 | RSS 聚合